class DROP_DOWN{
  
  //Initalize variables
  int x, y;
  float menuLength, optionHeight;
  String heading, lable; //where heading is selected option and lable is the String describing the drop down menu
  String [] optionsArray;
  color mouseOut, mouseOver, mouseClick;
  boolean menuOpen;
  BUTTON [] buttonsArray;
  
  //Attributes
  DROP_DOWN(int xTEMP, int yTEMP, int intialValue, String [] optionsArrayTEMP, String lableTEMP){
    
    //Assign attributes
    x = xTEMP;
    y = yTEMP; //where the user enters the coordinates of the top left corner of the lable
    optionsArray = optionsArrayTEMP;
    lable = lableTEMP;
    
    optionHeight = textAscent()+textDescent()+6;
    
    menuLength = 0;
    for (int i=0; i<optionsArray.length; i++){
      if (textWidth(optionsArray[i])>menuLength){
        menuLength = textWidth(optionsArray[i])+10;
      }
    }
    
    //Translate the coordinates so that x and y are the coordinates for the menu
    x+=textWidth(lable);
    
    //Setup
    heading = optionsArray[intialValue];
    menuOpen = false;
    
    //Creates an array of buttons which will respresent the drop down menu
    buttonsArray = new BUTTON [optionsArray.length];
    for (int i=0; i<optionsArray.length; i++){
      buttonsArray[i] = new BUTTON(x, y+((i+1)*optionHeight), optionsArray[i], menuLength);
    }
  }
  
  //Methods
  
  //display the menu
  void display(){
    
    //displays the menu if it is open
    if (menuOpen==true){
      for (byte i=0; i<optionsArray.length; i++){
        buttonsArray[i].display();
      }
      fill(Attention);
    }
    
    //highlight the box if the mouse is over it
    else if (((mouseX>x)&&(mouseX<x+menuLength)&&(mouseY>y)&&(mouseY<y+optionHeight))){
      fill(Hover);
    }
    
    else {
      fill(Foreground);
    }
    
    //draw the drop down heading
    rect(x,y,menuLength,optionHeight);
    
    fill(Outline);
    text(heading,x,y+textDescent()+textAscent());
    
    text(lable,x-textWidth(lable),y+textDescent()+textAscent());
  }
  
  //open or close the menu when the mouse is clicked
  void activate_menu(){
    //if mouse is on the menu, open or close the menu
    if (((mouseX>x)&&(mouseX<x+menuLength)&&(mouseY>y)&&(mouseY<y+((buttonsArray.length+1)*optionHeight)))){
      if (((mouseX>x)&&(mouseX<x+menuLength)&&(mouseY>y)&&(mouseY<y+optionHeight))){
        menuOpen= !menuOpen;
      }
    }
    else {
      menuOpen = false;
    }
  }
  
  void close_menu(){
    menuOpen=false;
  }
  
  //Returns a value
  int return_value(){
    if (menuOpen==true){
      //find the button in which is under the mouse and return its position in the array
      for (int i=0; i<buttonsArray.length; i++){
        buttonsArray[i].clickedMouseX = mouseX;
        buttonsArray[i].clickedMouseY = mouseY;
        if (buttonsArray[i].return_value()==true){
          heading = optionsArray[i];
          return i;
        }
      }
      //if the mouse is out of the menu close it
      if (!(((mouseX>x)&&(mouseX<x+menuLength)&&(mouseY>y)&&(mouseY<y+((buttonsArray.length+1)*optionHeight))))){
        this.close_menu();
      }
    }
    //return a flag '-1' if the menu is not open and a return value is not vaild
    return -1;
  }
}